home *** CD-ROM | disk | FTP | other *** search
/ BBS in a Box 3 / BBS in a box - Trilogy III.iso / Files / Prog / A / Acius08⁄92 / Encoding⁄Decipheringƒ / Sources / EncryptPicture.a < prev    next >
Encoding:
Text File  |  1992-08-17  |  3.6 KB  |  127 lines  |  [TEXT/MPS ]
  1. ;
  2. ; Encoding pictures external routine for 4D
  3. ; written by François Marchal, © ACI 1992
  4. ; 
  5. ; Parameters :
  6. ; -> Picture to encode
  7. ; -> Longint key word (you need the same key to encode and to decipher the picture)
  8. ;
  9.  
  10.     CASE    OBJ
  11.     INCLUDE 'traps.a'
  12.     
  13. picsize            EQU        104
  14. cle                EQU        100
  15. signature        EQU        98
  16. masignature        EQU        $464D
  17. picend            EQU        6
  18.  
  19.     EXPORT        EncryptPicture
  20.  
  21. EncryptPicture    PROC         
  22.     CODE
  23.  
  24.     LINK        A6,#$0
  25.     MOVEM.L        D4-D7/A4,-(A7)            ; save the used registers
  26.     MOVEA.L        12(A6),A4
  27.     MOVE.L        (A4),A4                    ; A4 : Handle on the picture to encode
  28.     BEQ            Fini                    ; if the Handle passed is Nil, don't do anything
  29.  
  30.     MOVE.L        (A4),A0    
  31.     MOVE.W        signature(A0),D0
  32.     CMPI.W        #masignature,D0            ; verify if the handle hasn't been signed
  33.     BEQ            fini                    ; if the picture has already been encoded, don't do anything
  34.     
  35.  
  36.     MOVE.L        A4,A0
  37.     _GetHandleSize
  38.     MOVE.L        D0,D7                    ; store the size of the Handle in D7
  39.     BEQ.S        Fini                    ; If the Handle is empty, stop
  40.  
  41.     MOVE.L        A4,A0                    ; to insert the lock here
  42.     ADD.L        #picsize,D0                ; make the Handle as big as the size of the new picture
  43.     _SetHandleSize
  44.     MOVE.W        D0,D0
  45.     BMI.S        Fini
  46.     
  47.     SUBQ.L        #picend,D7
  48.     MOVE.L        (A4),A0
  49.     ADDA.L        D7,A0                    ; move the 6 bytes from the picend 
  50.     MOVEA.L        A0,A1                    ; to the end of the block
  51.     ADDA.L        #picsize,A1
  52.     MOVE.L        (A0)+,(A1)+
  53.     MOVE.W        (A0)+,(A1)    
  54.                                         ; take the old header of the picture and place it at the end of the block
  55.     MOVE.L        (A4),A0                    ; Source -> move the pointer to the beginning of the data
  56.     MOVE.L        A0,A1                    ; Dest   -> calculate a pointer to the end of the data
  57.     ADDA.L        D7,A1                    ; 
  58.     MOVE.L        #picsize,D0                ; Lenght -> the size of the header
  59.     _BlockMove                            ; move the header to the end of the block
  60.  
  61.     LEA            Verrou,A0                ; Source -> take the address of the data of the lock
  62.     MOVE.L        (A4),A1                    ; Dest   -> take the Handle dereferened
  63.     MOVE.L        #picsize,D0                ; Lenght -> number of bytes to move
  64.     _BlockMove                            ; place our own header at the beginning of the picture
  65.     
  66.  
  67.     MOVE.L        8(A6),A0                ; dereferencing (parameter passed in var)
  68.     MOVE.L        (A0),D4                    ; of the encoding key
  69.     MOVE.L        (A4),A0                    ; saving of the key after the signature
  70.     MOVE.L        D4,Cle(A0)                ;
  71.  
  72.     MOVE.L        (A4),A0
  73.     ADDA.L        #Picsize,A0                ; A0 : pointer to the data to encode
  74.  
  75.     MOVE.L        D7,D6
  76.     ANDI.L        #$1F,D6                    ; D6 -> the remainder of the whole division of D7 by 32
  77.  
  78.     LSR.L        #5,D7                    ; divide by 32 of the size of the Handle
  79.     BEQ.S        GereReste                ; allows us to know the number of passes in the loop
  80.  
  81.     SUBQ        #1,D7                    ; take 1 to D7 for the dbra
  82.  
  83. Loop:
  84.     MOVE.L        D4,D5
  85.     SUB.L        D7,D5
  86.     EOR.L        D5,(A0)+                ; 1
  87.     EOR.L        D5,(A0)+                ; 2
  88.     EOR.L        D5,(A0)+                ; 3
  89.     EOR.L        D5,(A0)+                ; 4
  90.     EOR.L        D5,(A0)+                ; 5
  91.     EOR.L        D5,(A0)+                ; 6
  92.     EOR.L        D5,(A0)+                ; 7
  93.     EOR.L        D5,(A0)+                ; 8 x 4 = 32 bytes processed by the loop
  94.     
  95.     DBRA        D7,Loop                    
  96.  
  97. GereReste:                                ; take care of the remaining bytes
  98.     CMPI.L        #0,D6
  99.     BLE.s        Fini
  100.     EOR.B        D6,(A0)+
  101.     SUBQ        #1,D6
  102.     BRA.S        GereReste
  103.     
  104. Fini:    
  105.     MOVEM.L        (A7)+,D4-D7/A4            ; restoring the registers
  106.     UNLK        A6
  107.     MOVEA.L        (A7)+,A0                ; read the return address
  108.     ADDQ.L        #$8,A7                    ; take the parameters off of the stack
  109.     JMP            (A0)                    ; and return to the calling point
  110.  
  111. Verrou:    
  112.     DC.B        $00,$61,$00,$00,$00,$00,$00,$10,$00,$10        ; lock picture
  113.     DC.B        $11,$01,$A0,$00,$82,$A0,$00,$8E,$01,$00
  114.     DC.B        $0A,$00,$00,$00,$00,$00,$10,$00,$10,$90
  115.     DC.B        $00,$02,$00,$52,$00,$7E,$00,$62,$00,$8E
  116.     DC.B        $00,$52,$00,$7E,$00,$62,$00,$8E,$00,$00
  117.     DC.B        $00,$00,$00,$10,$00,$10,$00,$00,$00,$00
  118.     DC.B        $07,$C0,$0F,$E0,$1C,$70,$18,$30,$18,$30
  119.     DC.B        $18,$30,$3F,$F8,$3F,$F8,$3C,$78,$3C,$78
  120.     DC.B        $3E,$F8,$3E,$F8,$3F,$F8,$3F,$F8,$00,$00
  121.     DC.B        $A0,$00,$8F,$A0,$00,$83,$FF,$00
  122.  
  123.     DC.W        masignature
  124.     DC.L        $0
  125.     
  126.     ENDP    
  127.     END